詰めSAS10回目_変数内の1文字ごとにオブザベーションを起こす

この問題はまだ納得できる最適解がでていません。お力を貸してください。
また、1手では無理だと思います。

今、以下のようなデータセットがあったとします。

data Q1;
X='ABCDE';output;
X='12';output;
X='WXYZ';output;
run;








ここから以下のようなデータセットを作りたいとします










一文字ごとにobsになりX_○の、○の部分は元のデータセットのオブザベーション番号です。

問題は3obsですが、何オブザベーションになったとしても動き、かつ対象変数Xの変数の長さが
いくつになっても動くプログラムを書くことが問題となります。
ただし、めんどうなので今回はXの中には半角英数字(1byte文字)しか入らないという前提条件をつけます。


【解法1:悪手】

最初に思いついたのは以下の一連の流れです


/*オブザベーション数と対象変数のlengthをマクロ変数に代入*/
data _NULL_;
  set Q1 nobs=tobs;
  call symputx('obs',tobs);
  call symputx('len',length(X));
 stop;
run;

/*変数内の一文字ごとにobsを起こすマクロ*/
%macro separate(po);
data A&po;
  PT=&po;
 set Q1 point=PT;
   do i=1 to &len;
     X_&po=char(X,i);
output;
   end;
 stop;
 run;
%mend;

/*separateマクロの対象を元DSの1obsずつ最後までずらすマクロ
  ついでにループ変数でマージして完成まで*/
%macro loop;
 %do i=1 %to &obs;
  %separate(&i)
 %end;
 data OUTPUT;
  merge A:;
  by i;
  drop X i;
 run;
%mend;

/*実行*/
%loop


ようは1obsごとに、変数内の1文字ごとに1obsとなるデータセットをそれぞれ作り


























それをマージで連結するという発想でした。

局面を細かく区切ってマクロループに頼るのは大局感を欠いた悪手になりがちですが
今回もそんな感じがしますね。


【解放2:まだマシか】

data _NULL_;
  set Q1;
  call symputx('len',length(X));
  stop;
run;

data AA1;
 set Q1;
  array AX(&len) $1;
  do i=1 to &len;
   AX(i)=char(X,i);
  end;
  IDNO=_N_;
  drop i;
run;

proc transpose data=AA1 out=OUTPUT2(drop=_NAME_) prefix=X_;
 var AX:;
 id IDNO;
run;

先に変数内の文字区切りから横に展開して変数を作ります。







↑データセット[AA1]の中身

これを転置して完成です。

オブザベーション数を取得していないので、1手得してます。
また1データステップ内で横にループはしていますが、データステップ自体をループしていないので
先の方法よりかはずいぶん効率がいいです。


でも、あんまり美しくないので、もっといい答えがあれば教えてください。


実践的な問題ではない??
詰め将棋だってそんなもんです。
たとえ非現実的な局面の問題でも、解けば棋力の底上げになるはずです。




干支の出し方

干支の判別方法を聞いたので、書いてみた。

data _NULL_;
X=2014;
select(mod(X,12));
 when(0) ETO='申(さる)';
 when(1) ETO='酉(とり)';
 when(2) ETO='戌(いぬ)';
 when(3) ETO='亥(い)';
 when(4) ETO='子(ね)';
 when(5) ETO='丑(うし)';
 when(6) ETO='寅(とら)';
 when(7) ETO='卯(う)';
 when(8) ETO='辰(たつ)';
 when(9) ETO='巳(み)';
 when(10) ETO='午(うま)';
 when(11) ETO='未(ひつじ)';
 end;
put X "年の干支は" ETO;
run;








うん、2014年と自分の干支でしか確認してないけど、多分あっている。
もっと細かい干支(60年周期のやつ)も同じようなやりかたでだせる。


WHICHC、WHICHN関数の話

使えそうな機能を持っているから、機会があれば、使おうと思いつつ、あんまり使ったことない
which関数です。いや、関数が悪いのではなく使いどころをうまく作れない僕がヘボなんですが。
いつものごとく、cがつけば対文字型、nがつけば対数値型です。

例えば以下のようなデータセットがあったとします。

data Q1;
A='い';X='い';Y='ろ';Z='は';output;
A='B';X='A';Y='B';Z='C';output;
A='D';X='A';Y='B';Z='C';output;
run;








X,Y,Zの変数の値の中に、Aの変数の値と一致するものがあるか?
ある場合は最初に一致するのが何番目の変数であるかの位置を数字で返す関数です。

一致するものがない場合は0を返します。
例えば、以下

data A1;
 set Q1;
  array TARGET{*} $ X Y Z;
  W=whichc(A,of TARGET(*));
run;


とすると結果は








です。

応用効きそうな匂いがかなりするんですが、実用例や工夫をご存じの方がいれば
ご教示ください。



SASで音楽を奏でる方法_call soundルーチンで音を鳴らす

まず、PCのスピーカーをONにして、PCで音が流せる状態にしてください。

SASプログラミングで、音を作成できることをご存じでしたでしょうか?
call soundルーチンを使います。引数は二つで、一つは周波数(1秒あたり)、
もう一つは発音時間(ミリ秒指定)です。


以下を実行してみてください。

data _NULL_;
 call sound(1000,200);
run; 

「ピッ♪」と音が鳴ったと思います。

次に周波数をあげてみます。

data _NULL_;
 call sound(10000,200);
run; 

「キッ♪」のような決して心地よくない高い音がなったはずです。

流れる時間を変えてみましょう

data _NULL_;
 call sound(1000,2000);
run; 

「ピーーー♪」となります。

さあ、後は、パラメータをいじりながら、連続でステートメントを書きまくれば作曲できます。
間を置きたい時は

data _NULL_;
 call sound(1000,200);
 call sleep(1000);
 call sound(1000,200);
run; 

のようにcall sleepルーチンを使えば、OKです。
さあ、自由に奏でましょう!


と言って、実際、やる人いませんよね。
ただ、世の中にはヒマ人、奇特な方がいらっしゃって、SAS call soundなので検索すれば
洋楽ですが、SASで再現されていたりします。

もっとドとかレとかなら、まだいけそうなのに、、。

で、実際、実践で使いどころがあるのかといえば、ありますよ!!
異常なデータを検知したり、エラーが出たときに、音で知らせるということです。
ログを常にチェックするのが大切ですが、実行が大量になるプログラムの場合、
何か異常があれば音を鳴らすコードを要所要所に入れておけば、見落としや、外れ値の疑い
のあるデータを見つけやすいです。
まあ、やってませんけどね。

あとは、嫌がらせで、人にあげるコードに、ガラスをひっかいたような音を再現して、延々流す
とかでしょうか??


SUBSTR(変数名,1,1)やSUBSTR(変数名,N,1)のような一字抜きであればFIRST関数、CHAR関数が使えるという話

例えば

data Q1;
 X='ABCDEFG';
 A=substr(X,1,1);
 B=substr(X,3,1);
run;

AはXから先頭1文字をとってきて、Bは3番目の文字をとります。
これで、問題ないです。





文句のつけようのないコードですが、敢えて無理やり文句をつけてみます。

まず、引数が3つもいるのが面倒臭い。
そして、今作成されたA、BのLENGTHは元のXのLENGTHを継承するため
$7です。一字だけとってるんだから、長さは$1あれば必ず足りるのに6も余計な
領域使っていて、無駄だ!エコでない!

というわけで、上記のコードは、必ず先頭1文字を取得するFIRST関数と、指定した場所を
1文字抜くCHAR関数で

data A1;
 X='ABCDEFG';
 A=first(X);
 B=char(X,3);
run;

とかけます。






この場合、A、Bの長さは$1です。

ちなみに最後の1文字をとる関数については、多分ないので

A=first(reverse(X));

のようにreverse関数で逆さ読みにしてから、firstかけてください。





IFステートメントにおけるLAG関数の挙動の話

明けましておめでとうございます。今年もよろしくお願いします。

さて、以前IFステートメントでlag関数を使うときは注意が必要といったことを書いたような気がしますが、具体的にどういうことなのかを書きます。

実はSASのHPに同じことが書いているんですが、、申し訳ないけど、
いや、はっきり言ってわかりにくい!
http://www.sas.com/offices/asiapacific/japan/service/technical/faq/list/body/ba096.html


例えば以下のようなデータセットがあったとします。

data Q1;
X=1;output;
X=3;output;
X=2;output;
X=4;output;
X=5;output;
X=0;output;
X=6;output;
run;













今、やりたい処理が

「Xの値が3未満の場合、ひとつ前のXの値をYという変数に入れる」
という処理の場合、

data A1;
 set Q1;
 if X<3 then Y=lag(X);
run;

と書いてしまいそうなのですが、結果は












見当違いの悪手失着です。
あれ?一つ前だから、3obsは3,6obsは5じゃないの??といった感じですが、
実は上記のコードで実現されたのは
「Xの値が3未満の場合、ひとつ前にXが3未満であったときの値をYという変数に入れる」

という処理です。つまりIF条件式を通過したobsをカウントして、lagなら1つ前、lag2なら2つ前というように考えるのです。


挙動さえ理解していれば、条件に合致した前の値をとるといった処理が書きたい時に

data A0;
 set Q1;
 retain Y_;
 if X<3 then do;
  Y=Y_;
  Y_=X;
 end;
 drop Y_;
run;

のように第一感で浮かぶretainステートメントを使う必要もなく、コードがコンパクトになります。


ちなみに、最初に書いた「Xの値が3未満の場合、ひとつ前のXの値をYという変数に入れる」
をやりたい場合は

data A1;
 set Q1;
 Y_=lag(X);
 if X<3 then Y=Y_;
 drop Y_;
run;




のように、一度単純にlag関数を使って値を割り当ててから、IFします。








SASクエリウインドウの便利さについて

SASデータセットを開いて、ぱっと条件かけて抽出したい時に右クリック→[WHERE]で
























WHERE式ビルダを立ち上げて確認のための一時的な抽出をしたりすることがあると思います。 特に<定数値の参照>でその変数のバリエーションを全てリストしてくれたりして
とても便利ですが、以下の点で個人的に不満でした。

・抽出結果について変数選択ができないため全変数がでてきて、横に長いデータセットを見る場合はスクロールが面倒。行をハイライトしていても、ちょっとずれて、どのSUBJIDかわからなくなることがある
・抽出結果をそのままデータセットにできない。WHERE式で確認した後、データセットとして欲しくなっても結局コード書いて作らなければいけない
・一つのデータセットに対してしか見れない。複数のデータセットを繋いで抽出したい場合にコードを書いて予めマージしたデータセットを作らなければならない。

面倒がらずにコード書いてちゃんと導出しなさいという話で終わりですが、便利機能としてSASクエリウインドウを紹介します。正式名はSQLクエリウインドウだったんですね、最近知りました。 



SASの「ツール」→「クエリ」をクリックするか








コマンドウインドウという部分に「query」と打ってEnterします。
 クエリウインドウが立ち上がるので













抽出元のデータセットを好きなだけ選択します。テーブルソースというところは
参照するライブラリを選択する箇所になります。

OKを押すと、次は出力変数の選択画面になります
















ここで、もし複数データセットを選択していた場合、
先に右クリック→「テーブルの結合」で繋ぎ方と繋ぐ変数を設定しておかないと
勝手に直積結合しやがるので注意してください。

















あとは、出力する変数を選択して、抽出条件を追加したいなら右クリックメニューから
whereやhavingを設定したり、変数選択画面で、変数名をリネームしたりラベルつけたり、
またSQLでできることはほぼ何でも設定できるので、とりあえず色々いじって試してみてください。

















設定が完了後、右クリック→「クエリの実行」をすると結果がアウトプットウインドウに出力されます。









「クエリの表示」をクリックすると、設定した内容がSQL文に変換されて表示されます。










しかも、その画面の右には













こういうボタンがついていて、例えばテーブルの作成を選ぶと
現在の抽出結果でデータセットをこさえてくれます。

どうですか?ちょっとSQLかじってないとわかりにくいかもしれませんが、
凄くないですか?

まあ、GUIで楽にできるっていっても、結構手数かかってるやん、SAS書きならコードを早く書けるように練習しとけって感じもしますが、けど実際
使いなれている人がこれで、どんどんデータを確認しているところを横で見ていたことが
あるんですが、ボタンの配置を多分全部覚えていて、凄まじいスピードで、抽出を繰り返して、必要なデータをデータセット化してて、これはどれだけタイピング早くても、コードじゃおっつかないなと思ったことあります。


ちなみに日本語版SASオンラインヘルプに

SAS 9.3 SQLクエリウィンドウ ユーザーガイドが公開されていて、この機能だけについて100ページぐらい詳細な使い方が書いてあるので、極めんとするかたは読んで、面白いことがあれば教えてください。僕も、読もうと思ったのですが、途中で面倒になってやめてしまいました。