symbolimageでグラフのシンボルに好きな画像を使う方法。例えば散布図で将棋盤を表現

SAS9.4から、SG系グラフでsymbolimageを使うことができ、プロットのシンボルを自由な画像にすることができます。

印象としては、実装遅くない？って感じですよね。結構大事な機能だと思うので9.2から入れりゃいいのに、、。


で、今回はGTL＆SGRENDERで散布図書きます。
で、どうせなら、散布図の概念に捉われない使い方をしたいと思います。

今、以下のようなデータセットがあったとします。

data Q1;
X=1;Y=9;KOMA='▲香車';output;
X=2;Y=9;KOMA='▲桂馬';output;
X=3;Y=9;KOMA='▲銀将';output;
X=4;Y=9;KOMA='▲金将';output;
X=5;Y=9;KOMA='▲王将';output;
X=6;Y=9;KOMA='▲金将';output;
X=7;Y=9;KOMA='▲銀将';output;
X=8;Y=9;KOMA='▲桂馬';output;
X=9;Y=9;KOMA='▲香車';output;
X=2;Y=8;KOMA='▲飛車';output;
X=8;Y=8;KOMA='▲角行';output;
X=1;Y=7;KOMA='▲歩兵';output;
X=2;Y=7;KOMA='▲歩兵';output;
X=3;Y=7;KOMA='▲歩兵';output;
X=4;Y=7;KOMA='▲歩兵';output;
X=5;Y=7;KOMA='▲歩兵';output;
X=6;Y=7;KOMA='▲歩兵';output;
X=7;Y=7;KOMA='▲歩兵';output;
X=8;Y=7;KOMA='▲歩兵';output;
X=9;Y=7;KOMA='▲歩兵';output;
X=1;Y=1;KOMA='△香車';output;
X=2;Y=1;KOMA='△桂馬';output;
X=3;Y=1;KOMA='△銀将';output;
X=4;Y=1;KOMA='△金将';output;
X=5;Y=1;KOMA='△王将';output;
X=6;Y=1;KOMA='△金将';output;
X=7;Y=1;KOMA='△銀将';output;
X=8;Y=1;KOMA='△桂馬';output;
X=9;Y=1;KOMA='△香車';output;
X=8;Y=2;KOMA='△飛車';output;
X=2;Y=2;KOMA='△角行';output;
X=1;Y=3;KOMA='△歩兵';output;
X=2;Y=3;KOMA='△歩兵';output;
X=3;Y=3;KOMA='△歩兵';output;
X=4;Y=3;KOMA='△歩兵';output;
X=5;Y=3;KOMA='△歩兵';output;
X=6;Y=3;KOMA='△歩兵';output;
X=7;Y=3;KOMA='△歩兵';output;
X=8;Y=3;KOMA='△歩兵';output;
X=9;Y=3;KOMA='△歩兵';output;
run;

ちなみに▲は先手を表し、△は後手を表す将棋の符号です。

で、任意のフォルダに、フリー素材画像のサイトから駒の画像をとってきて保存します。

先手と後手で画像の向きがひっくり返りますが、ここは単純に反転した画像を用意して使います。
（使用したサイト：http://sozai.7gates.net/docs/japanese-chess/）

でコードは

ods path(prepend) work.templat(update);

proc template;

 define statgraph syogi;

 begingraph;

 symbolimage name=S_OU image='/folders/myfolders/koma/▲王将.png';

 symbolimage name=S_HISYA image='/folders/myfolders/koma/▲飛車.png';

 symbolimage name=S_KAKU image='/folders/myfolders/koma/▲角行.png';

 symbolimage name=S_KINN image='/folders/myfolders/koma/▲金将.png';

 symbolimage name=S_GINN image='/folders/myfolders/koma/▲銀将.png';

 symbolimage name=S_KYOUSYA image='/folders/myfolders/koma/▲香車.png';

 symbolimage name=S_KEIMA image='/folders/myfolders/koma/▲桂馬.png';

 symbolimage name=S_HU image='/folders/myfolders/koma/▲歩兵.png';

 symbolimage name=G_OU image='/folders/myfolders/koma/△王将.png';

 symbolimage name=G_HISYA image='/folders/myfolders/koma/△飛車.png';

 symbolimage name=G_KAKU image='/folders/myfolders/koma/△角行.png';

 symbolimage name=G_KINN image='/folders/myfolders/koma/△金将.png';

 symbolimage name=G_GINN image='/folders/myfolders/koma/△銀将.png';

 symbolimage name=G_KYOUSYA image='/folders/myfolders/koma/△香車.png';

 symbolimage name=G_KEIMA image='/folders/myfolders/koma/△桂馬.png';

 symbolimage name=G_HU image='/folders/myfolders/koma/△歩兵.png';

 discreteattrmap name='kifmap';

   value '▲王将' / markerattrs=(symbol=S_OU);

   value '▲飛車' / markerattrs=(symbol=S_HISYA);

   value '▲角行' / markerattrs=(symbol=S_KAKU);

   value '▲金将' / markerattrs=(symbol=S_KINN);

   value '▲銀将' / markerattrs=(symbol=S_GINN);

   value '▲香車' / markerattrs=(symbol=S_KYOUSYA);

   value '▲桂馬' / markerattrs=(symbol=S_KEIMA);

   value '▲歩兵' / markerattrs=(symbol=S_HU);

   value '△王将' / markerattrs=(symbol=G_OU);

   value '△飛車' / markerattrs=(symbol=G_HISYA);

   value '△角行' / markerattrs=(symbol=G_KAKU);

   value '△金将' / markerattrs=(symbol=G_KINN);

   value '△銀将' / markerattrs=(symbol=G_GINN);

   value '△香車' / markerattrs=(symbol=G_KYOUSYA);

   value '△桂馬' / markerattrs=(symbol=G_KEIMA);

   value '△歩兵' / markerattrs=(symbol=G_HU);

 enddiscreteattrmap;

 discreteattrvar attrvar=KOMAC var=KOMA attrmap='kifmap';

 layout overlay /yaxisopts=(reverse=true griddisplay=ON

                            linearopts=(tickvaluesequence=(start=1 end=9 increment=1)))

                 xaxisopts=(reverse=true  griddisplay=ON

                            linearopts=(tickvaluesequence=(start=1 end=9 increment=1)));

    scatterplot x=X y=Y /group=KOMAC markerattrs=(size=25pt);

 endlayout;

 endgraph;

 end;

proc sgrender template=syogi data=Q1;

run;

結果は

てな、感じです。まだマス目がうまく表現できてないので、今後の課題ですね。

最後に「新手一生」を掲げられた升田幸三の言葉を2つほど

『文化なんてしょせん無駄なもんなんだ。でもその明かりが、届く範囲の人に何かをもらたしている。将棋も同じじゃないか』

『若い頃、全く生産性のない「将棋指し」という職業に寂莫とした思いをしたことがあります。国家に、国民に、いかほどの貢献をしているだろうかと。でも、文化というものはムダから発展していくのだ、ということを会得してからは「将棋指し」に打ち込めるようになりました。』

実績値と予測値とかの棒グラフをGTLで作る

以前、[GKPIプロシジャは見た目が楽しくて良いという話]
http://sas-tumesas.blogspot.jp/2014/09/gkpi.html

で、達成度と目標値みたいなプロットをあげました。遊び的な話題として書いたのですが、意外と受けたみたいで、売り上げと予測値の月毎の棒グラフにしたいが、どう書くかみたいなメールをいただいたりしました。

基本的にユーザーの要求に応じて、自由なグラフを書くなら、僕はもう基本的にはGTLを勉強して使うべきだと思います。つまりproc templateでグラフテンプレートを定義して、proc sgrenderでそれを適用するということです。

GTLは9.2では、まだ出はじめということで実際使用していて表現力が足りないなと感じる部分がありますが、9.3以降はannotateも使えますし、きちんとコードを書きさいすれば、基本的に思った通りのものを大体実現できると言っていいでしょう。

GTLは覚えるのは、かなり時間がかかりますが、GTLさえ覚えてしまえば、乱暴な話、sgplotとかsgscatterとかそれぞれのグラフを書くプロシジャなんて全く覚える必要なく、全部GTLでかけます。

内部的には全てGTLで動いてるから当たり前といえば当たり前で、根源的な存在なので、それさえ押さえとけば無敵です。
（ただ、さすがにgkpiプロシジャのスピードメーター表示みたいな特殊なものはGTLでも厳しいかも）

偉そうなこと言いつつ、僕はまだまだ全然ですが。
いつかきちんと勉強して1から解説します（そんなこと言ってばっかですけど）

data Q1;
TIME=1;ACTUAL=100;PREDICT=80;output;
TIME=2;ACTUAL=90;PREDICT=100;output;
TIME=3;ACTUAL=120;PREDICT=100;output;
TIME=4;ACTUAL=120;PREDICT=120;output;
TIME=5;ACTUAL=100;PREDICT=80;output;
run;

TIMEが月とか、日とか、要はX軸にもってくるやつで、ACTUALが実績値で、PREDICTが予測値とか目標値だとして

proc template;
 define statgraph G1;
 begingraph;
 layout overlay;
  barchart X=TIME Y=ACTUAL/target=PREDICT;
 endlayout;
 endgraph;
 end;
run;

proc sgrender data=Q1 template=G1;
run;

ポイントはtarget=です。

で結果は

こんな感じですね。

提示したのは必要最低限のパターンなので、ここから色つけたり、様々な飾りつけは、GTLを勉強して頑張ってみてください。

ods graphicsで作成される複合グラフを１つ１つのプロットに分解する話

データは適当です。

data Q1;
X=1;Y=4;output;
X=2;Y=5;output;
X=5;Y=8;output;
X=6;Y=9;output;
X=9;Y=12;output;
X=11;Y=10;output;
X=22;Y=26;output;
X=12;Y=15;output;
run;

ods graphicsが有効になっている状態で統計プロシジャをまわすと

ods graphics on;
proc reg data=Q1;
model Y = X;
run;
quit;
ods graphics off;

まあ、いっぱいプロットがでてきますよね。

試しに一つ開いてみると

こういう複合プロットってありますよね。
凄い見栄え綺麗なんですが、複合状態じゃなく、個々に独立したプロットとして出したい時が
あるとします。

その場合

だしたい複合プロットの名前を見てから

ods graphics on;
proc reg data=Q1 plots(only)=DiagnosticsPanel(unpack);
model Y = X;
run;
quit;
ods graphics off;

こんな感じで、(unpack)とつけてやります。そうすると

プロットが分解されます。

ここからはおまけですが、

例えば、ODS graphicsで作成される自動プロットも、内部的にはGTLで処理

されているわけなので、コードで再現可能なわけです。

例えば

さっき、分解したプロットのうちの一つですが、これってどんなコードで作られているんだろうかと

思ったら

また

プロパティみるのですが、今度は「テンプレート」って部分をみます

あとはテンプレートの表示タブから

階層をたどり

目当てのテンプレートを発見したらダブルクリックすれば

こんな感じで、さっきのグラフを作っているGTLを入手できます。

ちなみに僕は45度線の書き方がわからない時に、この方法でゲットしました。

ODS Graphics Editorの話 (特別なライセンスなし、SAS/GRAPHでできる便利な機能)

templateプロシジャで、Glaph Template Languageで、グラフのテンプレートを作って、proc sgrenderでそのテンプレートを指定して、プロットする。

SAS9.2以降、SG系グラフの登場により、グラフの表現力はケタ違いにアップしましたが、その代わり、最初のハードルも随分高くなってしまった気がします。

いきなりGTLガリガリ書いてグラフを作るのは、ちょっと難しいので、最初のうちは
SASのグラフサンプル集http://support.sas.com/sassamples/graphgallery/PROC_SGRENDER.html

やSASユーザー総会で公開されているものや、或いは書籍、コピペして、少しずつカスタマイズして
自分のものにしていくのがいいと思います。
リンクさせていただいている「僕の頁 <SASと臨床試験と雑談と>」（http://sasboku.blog.fc2.com/）
にもGTLを使ったプロットが公開されていて勉強になります。

で、今回紹介するのは、それとは違ったアプローチです。
GUI、ようはプログラムを書かずに手でグラフを書いて、それを自動的にコード化する話です。

まず、適当なデータをつくります。

data TEST;
call streaminit(2014);
do GROUP='A','B';
 do i=1 to 100;
  x=rand('uniform');
  y=rand('uniform');
  output;
 end;
end;
drop i;
run;


そしたら、まず、SASをインストールする時に、ODS Graphics Editerにチェックをつけた人は、すでにアイコンがあるか、すべてのプログラムから立ち上げられるので、そうしてください。

もし、そういったものが見当たらない人は

%sgdesign;

とエディタに書いて、実行してください。
何かが裏で凄い動いた感じがして、10数秒後、

こんな画面がでてきます。

ここで、いろんな形のグラフを選ぶことで、実は相当高度なグラフもかけます。

試しにグラフギャラリーから「グループ化散布図」でも選んでみましょう

グラフを選ぶと、次はグラフに使うデータセットを指定します。
デフォルトがなぜかSASHELPなので、参照元にするライブラリを指定します。


※ちなみにここで、%sgdesign;で起動した人は、WORKの中をみてみましょう。
わけわかんないデータセットであふれているはずですが、これは、グラフを書くサンプル用の
データセットを勝手に用意してくれいるんです。迷惑です。

で、最初につくったデータセットを指定します


そしたら

X軸に対応する変数とY軸に対応する変数、そしてグループ化する変数をプルダウンで
選びます。

そしたら、それだけで、グラフがポンとでてきます。
で、なんと、そのグラフを手で修正できます。

まずはグラフタイトルをクリックして、好きなタイトルにします

右クリックで、軸や背景などのいろんなプロパティをいじれます。
感覚的にはEXCELのグラフを編集するのと全く同じです。

背景色を灰色にしてみました。

要素の追加で、さらにプロットを重ねたり
フリーテキストや凡例などを追加できます

凡例を追加してみました

やりたい放題やって、気がすんだら、ここからが本番

表示から「コード」をクリックすると





なんと、proc templateでのテンプレート定義から
proc sgrenderの実行までを全てコード化してくれます。


プロットに指定した変数はdynamicステートメントで受け渡すことを想定したコード化を
してくれるので、標準化もしやすく、超便利。

あとはこれをエディタにペタ

proc template;
define statgraph sgdesign;
dynamic _X _Y _GROUP;
begingraph / backgroundcolor=CXE8E6E8;
entrytitle _id='title' halign=center '散布図ですわ' /;
entryfootnote _id='footnote' halign=left 'Type in your footnote...' /;
layout lattice _id='lattice' / columndatarange=data columngutter=10 rowdatarange=data rowgutter=10;
         layout overlay _id='overlay' / xaxisopts=(gridDisplay=on label='X軸のラベルも自由') yaxisopts=(linearopts=(viewmin=0.2 viewmax=0.9 ) tickvalueattrs=(size=12) gridDisplay=on type=linear);
            scatterplot _id='scatter' x=_X y=_Y / group=_GROUP name='scatter';
            discretelegend _id='legend' 'scatter'  / border=true displayclipped=true down=1 halign=center location=inside opaque=false order=columnmajor valign=top;
         endlayout;
endlayout;
endgraph;
end;
run;

proc sgrender data=WORK.TEST template=sgdesign;
dynamic _X="X" _Y="Y" _GROUP="GROUP";
run;

で実行するだけで

さっきまで、手でいじって作ってたグラフが、ポンです。

これは、GTLを勉強するとき、何と何が結びついているかを理解する上でも、大変役立ちますね。
レイアウト分割の複合グラフを、一からコードで起こすのは、まあ、なかなか、つらいですよね、それはそれで勉強になるけども